Date:         Thu, 5 Apr 2001 08:00:56 -0700
Reply-To:     Lauren Haworth <haworthl@GENE.COM>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         Lauren Haworth <haworthl@GENE.COM>
Organization: Genentech, Inc.
Subject:      Re: ODS PDF, PROC TEMPLATE, & PROC REPORT
Comments: To: kjb@ga.unc.edu
Content-Type: text/plain; charset=us-ascii

Keith,

Try this code:

PROC TEMPLATE;
   DEFINE STYLE NoBorders;
      PARENT=Styles.RTF;
      REPLACE Output from Container /
         rules = NONE
         frame = VOID
         cellpadding = 4pt
         cellspacing = 0;
      REPLACE Table from Output;
   END;
RUN;

The main difference is that this changes the rules settings in both the
Output and Table style elements. By the way, once you set frame=VOID and
rules=NONE, it doesn't matter what the setting is for borderwidth.

-- Lauren Haworth

"Keith J. Brown" wrote:

> Hi gang,
>    I've got a question that deals with the combination of the three
> SAS elements above.  Running V8.2 on a Solaris, I'm trying to produce
> PDF output from PROC REPORT.  I've used PROC TEMPLATE to blank out
> the lines between each line of text with BORDERWIDTH=0.  Unfortunately,
> what I'd really like to do is get rid of the lines entirely, so
> that I could bump up the font size to something legible, rather than
> 6.1pt.  Any suggestions?
>
> Keith Brown
>
> Partial code below:
>
> options ls=100 ps=79 source2 nodate;
>
> proc template;
> define style styles.kjb1;
> parent=styles.rtf;
> replace fonts /
>       'TitleFont2' = ("Courier",8pt,Bold Italic)
>       'TitleFont' = ("Courier",8pt,Bold Italic)
>       'StrongFont' = ("Courier",8pt,Bold)
>       'EmphasisFont' = ("Courier",8pt,Italic)
>       'FixedEmphasisFont' = ("Courier",8pt,Italic)
>       'FixedStrongFont' = ("Courier",8pt,Bold)
>       'FixedHeadingFont' = ("Courier",8pt,Bold)
>       'BatchFixedFont' = ("SAS Monospace, Courier",6.7pt)
>       'FixedFont' = ("Courier",8pt)
>       'headingEmphasisFont' = ("Courier",8pt,Bold Italic)
>       'headingFont' = ("Courier",8pt,Bold)
>       'docFont' = ("Courier",6.1pt);
> ;
> style table from table /
>   borderwidth=-1
>   frame=void
>   rules=none
> ;
> end;
> run;
>
> ods rtf file="scfvrfy3.rtf" style=styles.kjb1;
> ods pdf file="scfvrfy3.pdf" style=styles.kjb1;
> run;
>
> title1 "#byval(inst)";
> title2 "Comparative Statistics Between";
> title3 "&semester &yr5., &yr4., and &yr3 Student Courseload Files";
> run;
> footnote1
> "____________________________________________________________________"
> "                                                                    ";
> footnote2
> "UNC-OP ProgAssess/SCF Verify 3/&sysdate                             "
> "                                                                    ";
> run;
>
> proc report data=report1
>      nowindows spacing=1 headline;
> by inst;
> column page group line value3 value2 value1;
> define page / order order=internal noprint;
> define group / order order=internal noprint;
> define line / order  order=internal width=37
>        " ";
> define value3 / analysis "&yr5" width=15 format=comma9.;
> define value2 / analysis "&yr4" width=15 format=comma9.;
> define value1 / analysis "&yr3" width=15 format=comma9.;
> compute before group;
>    line @1 group group. ;
> endcomp;
> compute after page;
> line 'Page: ' page 2.;
> endcomp;
> break after page / page;
> break after group / suppress skip;
> run;
> quit;
>
> ods rtf close;
> ods pdf close;
> run;