Date:         Thu, 26 Sep 2002 10:21:21 -0400
Reply-To:     Matt Flynn <matt.flynn@THEHARTFORD.COM>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         Matt Flynn <matt.flynn@THEHARTFORD.COM>
Subject:      Re: Regression with Class Variables and Stepwise Selection
Comments: To: Charles <cwentzel@PHC4.ORG>

Charles:

For quick and easy recoding into k- dummy variables...see PROC GLMMOD.


   title 'Nitrogen Content of Red Clover Plants';
   data Clover;
      input Strain $ Nitrogen @@;
      datalines;
   3DOK1  19.4 3DOK1  32.6 3DOK1  27.0 3DOK1  32.1 3DOK1  33.0
   3DOK5  17.7 3DOK5  24.8 3DOK5  27.9 3DOK5  25.2 3DOK5  24.3
   3DOK4  17.0 3DOK4  19.4 3DOK4   9.1 3DOK4  11.9 3DOK4  15.8
   3DOK7  20.7 3DOK7  21.0 3DOK7  20.5 3DOK7  18.8 3DOK7  18.6
   3DOK13 14.3 3DOK13 14.4 3DOK13 11.8 3DOK13 11.6 3DOK13 14.2
   COMPOS 17.3 COMPOS 19.4 COMPOS 19.1 COMPOS 16.9 COMPOS 20.8
   ;
run;

   proc print data=Clover;
   run;
/*   Usually, you will find PROC GLMMOD most useful for the data sets it
can create*/
/*rather than for its displayed output. For example, the following
statements use PROC*/
/*GLMMOD to save the design matrix for the clover study to the data set
CloverDesign */
/*instead of displaying it. */


   proc glmmod data=Clover outdesign=CloverDesign;
      class Strain;
      model Nitrogen = Strain;
   run;

/*Now you can use the REG procedure to analyze the data, as the following
statements*/
/*demonstrate: */


   proc reg data=CloverDesign;
      model Nitrogen = Col3-Col7;
      test  Col3=0,Col4=0,Col5=0,Col6=0,Col7=0;
   run;