Date:         Tue, 22 Oct 2002 08:50:46 -0700
Reply-To:     David Rubanowice <rubanowice.d@GHC.ORG>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         David Rubanowice <rubanowice.d@GHC.ORG>
Subject:      Re: Using VB to call SAS
Content-Type: text/plain; charset=US-ASCII

If you want the spawned SAS process to finish before returning control to VB then Shell won't work (it's asynchronous in nature).  You can use Integrated Technologies if you want/have license/have patience, or you can use some Win32 calls like this.  Yes, I know it looks pretty complex, but it works great.  Pass the same command line to the ExecCmd routine just you're doing with Shell.  Copy and paste all of this code into a standard module in your VB project to make it easily reusable.  It's a LOT easier to do this in vb.net (2 lines of code in all) if that is an option.

'Source: http://groups.google.com/groups?q=win32+wait+for+process+vb&hl=en&selm=3352EFCA.6F98%40worldnet.att.net&rnum=2
Private Type STARTUPINFO
      cb As Long
      lpReserved As String
      lpDesktop As String
      lpTitle As String
      dwX As Long
      dwY As Long
      dwXSize As Long
      dwYSize As Long
      dwXCountChars As Long
      dwYCountChars As Long
      dwFillAttribute As Long
      dwFlags As Long
      wShowWindow As Integer
      cbReserved2 As Integer
      lpReserved2 As Long
      hStdInput As Long
      hStdOutput As Long
      hStdError As Long
   End Type
 
   Private Type PROCESS_INFORMATION
      hProcess As Long
      hThread As Long
      dwProcessID As Long
      dwThreadID As Long
   End Type
 
   Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
      hHandle As Long, ByVal dwMilliseconds As Long) As Long
 
   Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
      lpApplicationName As Long, ByVal lpCommandLine As String, ByVal _
      lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
      ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
      ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As Long, _
      lpStartupInfo As STARTUPINFO, lpProcessInformation As _
      PROCESS_INFORMATION) As Long
 
   Private Declare Function CloseHandle Lib "kernel32" (ByVal _
      hObject As Long) As Long
 
   Private Const NORMAL_PRIORITY_CLASS = &H20&
   Private Const INFINITE = -1&
 
   Public Sub ExecCmd(ByVal cmdline As String)
      Dim proc As PROCESS_INFORMATION
      Dim start As STARTUPINFO
 
      ' Initialize the STARTUPINFO structure:
      start.cb = Len(start)
 
      ' Start the shelled application:
      Dim ret As Long
      ret = CreateProcessA(0&, cmdline$, 0&, 0&, 1&, _
         NORMAL_PRIORITY_CLASS, 0&, 0&, start, proc)
 
      ' Wait for the shelled application to finish:
      ret = WaitForSingleObject(proc.hProcess, INFINITE)
      ret = CloseHandle(proc.hProcess)
   End Sub

>>> John Whittington <John.W@MEDISCIENCE.CO.UK> 10/22/02 08:15AM >>>
At 10:20 22/10/02 -0400, Bob Burnham wrote (in part):

>Finally, if you are looking for something very basic just to
>trigger a quick SAS job from VB, then something like this might
>be a good starting point:
>
>Private Sub ExecSAS(program As String, parameter As String)
>  Dim RetVal, sasPath
>  sasPath = "C:/program files/sas institute/sas/v8/sas.exe " + _
>   program + " -sysparm " + parameter
>  RetVal = Shell(sasPath, 6)
>End Sub

Bob, is that method actually meant to wait for the SAS (or whatever) job to
finish before returning control to VB - since it doesn't seem to work like
that whenever I try, which has caused me all sorts of problems!

Kind Regards,


John

----------------------------------------------------------------
Dr John Whittington,       Voice:    +44 (0) 1296 730225
Mediscience Services       Fax:      +44 (0) 1296 738893
Twyford Manor, Twyford,    E-mail:   John.W@mediscience.co.uk
Buckingham  MK18 4EL, UK             mediscience@compuserve.com
----------------------------------------------------------------