Date:         Thu, 10 Apr 2003 13:36:21 -0700
Reply-To:     "Huang, Ya" <yhuang@AMYLIN.COM>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         "Huang, Ya" <yhuang@AMYLIN.COM>
Subject:      Re: duplicate id while transposing
Comments: To: Sam <gowdar@ADVBIOL.COM>
Content-Type: text/plain; charset="iso-8859-1"

This one seems OK:

data xx;
input a b $ c $ d$ e;
cards;
  101 D1 DAN 1   1
  101 D2 DAN 1.1 1
  101 D3 DAN LD  1
  101 D1 DAN 2.2 2
  101 D2 DAN 2.3 2
  101 D3 DAN 2.0 2
;

data xx;
 set xx;
 by a c;
 if first.c then group=0;
 if b='D1' then group+1;

proc transpose data=xx out=yy (drop=group _name_) prefix=c;
by a c group;
var d;
run;

options nocenter;
proc print data=yy;
run;
------------
Obs     a      c     c1     c2     c3

 1     101    DAN    1      1.1    LD
 2     101    DAN    2.2    2.3    2.0

Kind regards,

Ya Huang

-----Original Message-----
From: Sam [mailto:gowdar@ADVBIOL.COM]
Sent: Thursday, April 10, 2003 1:07 PM
To: SAS-L@LISTSERV.UGA.EDU
Subject: duplicate id while transposing


The data is like this
  101 D1 DAN 1   1
  101 D2 DAN 1.1 1
  101 D3 DAN LD  1
  101 D1 DAN 2.2 2
  101 D2 DAN 2.3 2
  101 D3 DAN 2.0 2

it should be transposed as

 101    DAN      1      1.1    LD
 101    DAN      2.2    2.3    2.0


iF I USE LET IN TRANSPOSING, ITS GOING TO GIVE ONLY LAST OBSERVATION,
SO HOW TO GET THE OUTPUT.I AM USING DATA NULL

THANK YOU