Date:         Tue, 29 Apr 2003 10:19:17 -0700
Reply-To:     "Huang, Ya" <yhuang@AMYLIN.COM>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         "Huang, Ya" <yhuang@AMYLIN.COM>
Subject:      Re: Controlling haxis labels on gplot
Comments: To: gsnell@datasavantconsulting.com
Content-Type: text/plain; charset="iso-8859-1"

Hi Greg,

Looks like I miss understood your question in my previous
response. Here is another one, but the problem is that
it still won't work for device=java:

proc sql noprint;
select distinct put(date,best.)||"='"||put(date,date.)||"'"
 into :dslt separated by ' '
from drivers
;

proc format;
value dfmt
&dslt
other=' '
;

/*
ods listing close;
ods html body='c:\test.html' device=java
      parameters=("DisableDrillDown"="false"
                  "ColorScheme"="International"
                  "BackColor"="White");
*/

goptions reset=all;
goptions /*device=java*/ colors=(green red blue orange);

symbol1 interpol=join width=6 value=diamond;
symbol2 interpol=join width=6 value=diamond;
symbol3 interpol=join width=6 value=diamond;
symbol4 interpol=join width=6 value=diamond;

axis1 order='16nov2002'd to '16mar2003'd major=none minor=none;

proc gplot data=drivers;
  plot response*date=category
  / AUTOVREF cframe='grey'
    haxis=axis1 hminor=0
    href='16nov2002'd to '16mar2003'd by month
;
format date dfmt.;
run;
quit;


/*
ods html close ;
ods listing;
*/
goptions reset=all

I also tried device=activex with no luck.

Ya

-----Original Message-----
From: gsnell@datasavantconsulting.com
[mailto:gsnell@DATASAVANTCONSULTING.COM]
Sent: Tuesday, April 29, 2003 8:27 AM
To: SAS-L@LISTSERV.UGA.EDU
Subject: Controlling haxis labels on gplot


Hello sas/graph gurus!

There is probably an easy solution to my problem but I coulnd't find it
yesterday, hoping someone can help save me some time.

Here is a sample that generates a graph the way I want EXCEPT for the haxis
labels.

------------------------------------
data drivers;
  length heading category $32;
  format date date9.;
  heading = 'Instantiation';
  category = 'Instances';
  date = '01dec2002'd; response = 48; output;
  date = '01jan2003'd; response = 48; output;
  date = '01feb2003'd; response = 48; output;
  category = 'Applications';
  date = '01dec2002'd; response = 15; output;
  date = '01jan2003'd; response = 15; output;
  date = '01feb2003'd; response = 15; output;
run;

ods listing close;
ods html body='c:\test.html' device=java
      parameters=("DisableDrillDown"="false"
                  "ColorScheme"="International"
                  "BackColor"="White");

goptions reset=all;
goptions device=java colors=(green red blue orange);

symbol1 interpol=join width=6 value=diamond;
symbol2 interpol=join width=6 value=diamond;
symbol3 interpol=join width=6 value=diamond;
symbol4 interpol=join width=6 value=diamond;

proc gplot data=drivers;
  plot response*date=category / AUTOVREF cframe='gray'
                                haxis='16nov2002'd to '16mar2003'd by month
hminor=0
                                                                href='16nov2002'd to '16mar2003'd by month
                                ;
run;
quit;

ods html close ;
ods listing;

goptions reset=all ;
------------------------------------

I only want the dates to appear below the data points and NOT on the major
axis lines.  Why?  Because I am supposed to match an excel chart someone is
already producing for management.

Any suggestions you have will be greatly appreciated.

Regards,

Gregg P. Snell
Data Savant Consulting

--------------------------------------------------------------------
mail2web - Check your email from the web at
http://mail2web.com/ .