Date:         Thu, 12 Jun 2003 10:09:08 +0100
Reply-To:     "Ian(freeserve)" <ian@AZORUBINE.FREESERVE.CO.UK>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         "Ian(freeserve)" <ian@AZORUBINE.FREESERVE.CO.UK>
Subject:      Re: Proc Corr??
Content-Type: text/plain; charset="Windows-1252"

PROC MIXED can be used to find a confidence interval for
a correlation coefficient.  The idea appeared recently on
the allstat discussion list, see:

http://www.jiscmail.ac.uk/cgi-bin/wa.exe?A1=ind0306&L=allstat

I have used this to produce a small example below.  The
Toeplitz covariance parameter and the assoiciated Wald test
give the estimate of the correlation coefficient and the CI.

data corr;
  input x y;
  obs=_n_;
  cards;
  12 19
  10 15
  15 23
  16 16
  19 21
  23 25
  25 21
  27 26
  31 30
  36 27
;
proc corr data=corr nosimple;
  var x;
  with y;
/* Rearrange the data so both x and y are contained in
   the new variable Y1
*/
proc transpose data=corr out=corrlong name=varname prefix=y;
  by obs;
proc mixed data=corrlong alpha=0.05 cl=wald;
  class varname obs;
  model y1=varname /notest;
  repeated varname / type=toeph subject=obs;
run;

Dale, does this seem reasonable to you?

Ian.

Ian Wakeling
Qi Statistics.

> Date:    Wed, 11 Jun 2003 17:38:09 -0700
> From:    Dale McLerran <stringplayer_2@YAHOO.COM>
> Subject: Re: Proc Corr??
>
> Dennis,
>
> I don't believe that SAS produces confidence intervals about
> the correlation.  You will have to compute your own confidence
> limits by first applying the Fisher Z transformation
>
>     Z = 0.5 * log((1+corr)/(1-corr))
>
> The variance of Z is 1/(n-3).  Now compute confidence intervals
> for Z, assuming Z ~ normal.
>
>     Z(L) = Z - 1.96*sqrt(1/(n-3))
>     Z(U) = Z + 1.96*sqrt(1/(n-3))
>
> Back transform the confidence limits for Z to confidence limits
> on rho.
>
>    rho(L) = (exp(2*Z(L) - 1) / (1 - exp(2*Z(L)))
>    rho(U) = (exp(2*Z(U) - 1) / (1 - exp(2*Z(U)))
>
> Dale
>
>
> --- "Dennis G. Fisher" <dfisher@CSULB.EDU> wrote:
> > How does one obtain the confidence intervals for a correlation?   I
> > do
> > not see any mention of it in the version 8 Procedures guide for Proc
> > Corr.  Is there somewhere else I should be looking???  TIA
> > Dennis fisher
> >
> > --
> > Dennis G. Fisher, Ph.D.
> > Director
> > Center for Behavioral Research and Services
> > 1090 Atlantic Avenue
> > Long Beach, CA 90813
> > 562-495-2330
> > 562-983-1421 fax