Date:         Wed, 24 May 2006 10:07:42 +0100
Reply-To:     "Antro, Mark" <mantro@SPSS.COM>
Sender:       "SPSSX(r) Discussion" <SPSSX-L@LISTSERV.UGA.EDU>
From:         "Antro, Mark" <mantro@SPSS.COM>
Subject:      Re: AW: Syntax for computing variable for confidence interval
Comments: To: la volta statistics <schmidhauser@lavolta.ch>
Content-Type: text/plain; charset="US-ASCII"

Alternatively, you could run the explore procedure, use OMS to send the results to a new dataset and then merge back to the original...

Data List List /H_Id(F8.0) M_1(f8.0) M_2(f8.0).
BEGIN DATA
1 14 49
2 16 80
3 12 54
4 17 66
5 24 76
6 12 44
7 17 56
8 29 88
9 31 77
10 21 66
End Data.
DATASET NAME Org_Data.
COMPUTE dummy = 1.
EXE.
DATASET DECLARE Explore.
OMS
 /SELECT ALL
 /IF COMMANDS = ["Explore", "Dataset Name"]
 /DESTINATION VIEWER = NO.
OMS
 /SELECT LOGS
 /DESTINATION VIEWER = NO.
OMS
 /SELECT TABLES
 /IF COMMANDS = ["Explore"]
     SUBTYPES = ["Descriptives"]
 /DESTINATION FORMAT = SAV
  OUTFILE = Explore
 /TAG='exploretable'.

EXAMINE
  VARIABLES=M_1 M_2
  /PLOT NONE
  /STATISTICS DESCRIPTIVES
  /CINTERVAL 95
  /MISSING LISTWISE
  /NOTOTAL.

OMSEND TAG='exploretable'.

DATASET ACTIVATE Explore.

DEL VAR Command_ Subtype_ Label_ Var1 Var2 Std.Error.

SELECT IF (INDEX(Var3, "Bound") > 0).
EXE.

FLIP.
DATASET NAME Explore.

DEL VAR Case_Lbl.
COMPUTE dummy = 1.
use 2 thru  2 /permanent .
EXECUTE .

DATASET ACTIVATE Org_Data.

MATCH FILES /FILE=*
 /TABLE='EXPLORE'
 /BY dummy.
EXECUTE.

DATASET CLOSE Explore.
DEL VAR dummy.
OMSEND.