**Date:** Tue, 29 Jan 2008 16:30:30 +0100
**Reply-To:** Marta García-Granero <mgarciagranero@gmail.com>
**Sender:** "SPSSX(r) Discussion" <SPSSX-L@LISTSERV.UGA.EDU>
**From:** Marta García-Granero <mgarciagranero@gmail.com>
**Subject:** Re: Conditional logistic problems
**In-Reply-To:** <002701c861ea$4adf5150$2845cd80@ssw.buffalo.edu>
**Content-Type:** text/plain; charset=ISO-8859-1; format=flowed
Hi Gene:

See below a fully worked example, solved using the three approaches
(McNemar's OR with a MACRO, Mantel-Haenszel estimator and Conditional
logistic regression).

HTH,
Marta

(don't hesitate to ask me any question you might have concerning the syntax)

* Sample dataset (1:1 matched binary data, lower value means exposed in
both groups) *.
DATA LIST FREE/Case Control (2 F8).
BEGIN DATA
1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 2 1 2 1 2
1 2 1 2 1 2 1 2 1 2 1 2 1 2 1 2 1 2 1 2 1 2
1 2 1 2 1 2 1 2 1 2 1 2 1 2 1 2 2 1 2 1 2 1
2 1 2 1 2 1 2 1 2 1 2 2 2 2 2 2 2 2 2 2 2 2
2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2
2 2
END DATA.
VALUE LABEL Case Control 1'Exposed to Risk' 2 'Non exposed'.
LIST /CASES=FROM 1 TO 10.

* 1rst approach, valid only for 1:1 matched data, using a MACRO *.
* MACRO call (see my message to the list: "Re: Help with Matrix output
(& Paired data OR macro too, for H)"*.

PAIREDOR Case Control.

* 2nd approach: Mantel-Haenszel stratified analysis (valid for 1:1 or
1:k matched data) *.

* First of all, data need restructuring (using VARSTOCASES) *.
VARSTOCASES
/ID = pair
/MAKE Exposition 'Exposed to risk factor' FROM Case Control
/INDEX = Outcome(2).
VALUE LABEL Outcome 1'Case' 2 'Control'.

* MH OR (ignore all tables but the last) *.
CROSSTABS
/TABLES=Exposition BY Outcome BY pair
/FORMAT=NOTABLES
/STATISTIC=CMH(1)
/COUNT ROUND CELL .

* 3rd approach: Conditional logistic regression (thru Cox regression) *.
* We will start from the dataset we have just restructured *.
* We need three variables:
- Exposition -> it is already OK
- Pseudotime: should have these two values: 1 for cases and 2 for controls
we already have it (named outcome).
- Status: should have these two values: 0 for controls and 1 for cases
we must create it.

COMPUTE status=(outcome=1).

COXREG
Outcome /STATUS=status(1) /STRATA=pair
/CONTRAST (Exposition)=Indicator
/METHOD=ENTER Exposition
/PRINT=CI(95).

The three methods give the same result (as expected).
> All,
>
> I have been working with another list subscriber who has a matched (1:1)
> dataset and is trying to analyze relationships between variables using
> conditional logistic regression (CLR). I have no experience with this type
> of model. However, I did find a posting by Marta (shown below) as well as
> several discussion sites. Since spss logistic won't do a conditinal
> analysis, the trick is to use the coxreg procedure to do so. I believe I
> have faithfully followed Marta's directions but am getting no results and
> so, there is something I don't understand. Per Marta's posting, I have
>
> COXREG ftime /STATUS=outcome(1) /STRATA=pair
> /METHOD=ENTER x /PRINT=CI(95).
>
> Where
> Ftime is the survival time variable computed such that ftime=outcome+1.
> outcome is the case-control variable with 0=control, 1=case.
> Pair is the strata variable, 161 pairs.
> X is the IV.
>
> My case processing box shows
>
> Case Processing Summary
> N Percent
> Cases available in analysis Event(a) 161 50.0%
> Censored 0 .0%
> Total 161 50.0%
> Cases dropped Cases with missing values 0 .0%
> Cases with negative time 0 .0%
> Censored cases before the
> earliest event in a stratum 161 50.0%
> Total 322 100.0%
> a Dependent Variable: ftime
>
> Variables in the Equation(b)
> Wald df Sig.
> X . 0(a) .
> aDegree of freedom reduced because of constant or linearly dependent
> covariates
> bConstant or Linearly Dependent Covariates
> S = Stratum effect. x = .5093 + S;
>
>
> If somebody can educate me about what I'm missing or need to look at, I'd
> greatly appreciate it.
>
> Thanks, Gene Maguin
>
> =====================
> To manage your subscription to SPSSX-L, send a message to
> LISTSERV@LISTSERV.UGA.EDU (not to SPSSX-L), with no body text except the
> command. To leave the list, send the command
> SIGNOFF SPSSX-L
> For a list of commands to manage subscriptions, send the command
> INFO REFCARD
>
>

=====================
To manage your subscription to SPSSX-L, send a message to
LISTSERV@LISTSERV.UGA.EDU (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD