|
pisus.gsus@googlemail.com wrote:
> Hi,
>
> I have a problem using the skipmiss option together with the overlay
> option in proc gplot.
> I want to plot many data-series in one plot, thatīs why I use the
> overlay option.
> All of the data rows have many missing values, and sas is connecting
> them with a straight line, thatīs why I use the skipmiss option. But
> once skipmiss is in use either nothing is displayed in my diagramm or
> only one data-row is displayed until the first missing value. All
> other data are not ploted then.
>
> proc gplot data =xyz;
> plot ( a b c d e f g ) * x
> /overlay skipmiss
> vaxis=axis1 haxis=axis2
> legend=legend1;
> run;quit;
>
> I also tried the symbol option interpol=none, but there are aswell no
> data ploted.
>
> goptions reset=all;
> symbol1 i=j co=blue interpol=none;
Perhaps the data has so many missing values that no segment can be plotted.
This sample shows that skipmiss does work, and only contiguous valued points
in a series are connected.
------------------------
data xyz;
do x = 1 to 30;
array v a b c d e f g;
do _n_ = 1 to dim(v);
v (_n_) = _n_ * 2 + sin((x+_n_)/5);
if ranuni(123) < 0.3 then
v (_n_) = .;
end;
output;
end;
run;
ods listing;
goption reset=all goutmode=replace ftext='Arial';
legend1 label=('Legend One') ;
symbol1 v=dot i=join;
title 'skip missing';
proc gplot data =xyz;
plot ( a b c d e f g ) * x
/ overlay skipmiss
legend=legend1
;
run;
quit;
goptions goutmode=append ;
title 'no skip missing';
proc gplot data =xyz;
plot ( a b c d e f g ) * x
/ overlay
legend=legend1
;
run;
quit;
------------------------
Richard A. DeVenezia
| 
