Date:         Thu, 22 Oct 2009 09:18:47 -0500
Reply-To:     "Data _null_;" <iebupdte@GMAIL.COM>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         "Data _null_;" <iebupdte@GMAIL.COM>
Subject:      Re: MACRO FOR ALL POSSIBLE REGRESSIONS XXXX
Comments: To: Dan Abner <dan.abner99@gmail.com>
In-Reply-To:  <d18436ce0910220658j33d63075ka0f3c03666036def@mail.gmail.com>
Content-Type: text/plain; charset=ISO-8859-1

This may help http://support.sas.com/kb/24/986.html

The will produce a variable that will contains the RHS of the model on
record for each model.

data test;
   length x1-x10 8;
   call missing(of _all_);
   run;
proc summary data=test chartype missing;
   class x1-x10;
   output out=comb(drop=_freq_);
   run;
data allmodels;
   set comb;
   array x[*] x:;
   length rhs $200; *may need to be bigger;
   do i = 1 to dim(x);
      if substr(_type_,i,1) eq '1' then rhs = catx(' ',rhs,vname(x[i]));
      end;
   drop x: i;
   run;
proc print;
   run;



On 10/22/09, Dan Abner <dan.abner99@gmail.com> wrote:
> Hello everyone,
>
> I have a situation where I need to check the sample size requirements for a
> large number of potential binary logit models. I already have a macro to do
> this, but do not know how to augment it to handle all possible regressions
> for around 10 potential explanatory variables.
>
> I can easily write separate code to evaluate all 2 var models, then all 3
> var models, etc., but haven't figured out yet how to write a macro general
> enough to evaluate all possible regs dynamically.
>
> Any suggestions would be greatly appreciated.
>
> Thanks!
>
> Dan
>
> XXXX
>