Date:         Fri, 14 Jan 2011 17:28:02 -0600
Reply-To:     Joe Matise <snoopy369@GMAIL.COM>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         Joe Matise <snoopy369@GMAIL.COM>
Subject:      Re: PROC REPORT - Across variables and cell widths in HTML output
Comments: To: Sterling Paramore <gnilrets@gmail.com>
In-Reply-To:  <AANLkTinTYxq+B+FA0W0=2_Oq1mYkwN2H=qATBhOL23+_@mail.gmail.com>
Content-Type: text/plain; charset=ISO-8859-1

I think that the problem is that for the ACROSS variable, it takes its width
from ClaimLine_Allow_Amt.  For example, this does not work:
ods html;
proc report data = sashelp.class nowd;
   columns name weight,age;
   define name / group style(header) = [cellwidth=6in];
   define age / across style(column) = [cellwidth=5in];
   define weight / '' analysis sum;
run;
ods html close;

But this does:
ods html;
proc report data = sashelp.class nowd;
   columns name weight,age;
   define name / group style(header) = [cellwidth=6in];
   define age / across ;
   define weight / '' analysis sum style(column)= [cellwidth=5in];
run;
ods html close;

-Joe

On Fri, Jan 14, 2011 at 5:10 PM, Sterling Paramore <gnilrets@gmail.com>wrote:

> Dear SAS-L,
>
> I'm having trouble setting cellwidths with PROC REPORT when I have an
> across
> variable.  For example, the following code produces some ridiculously wide
> columns (so I can test that it's working):
>
>
> proc report data = SASUSER.example;
>    where Claim_Incurred_yrmo >= 201001;
>    columns Claim_Class_Id Claim_Incurred_yrmo ClaimLine_Allow_Amt ;
>
>    define Claim_Class_Id / group style(header) = [cellwidth=6in];
>    define Claim_Incurred_yrmo / group style(column) = [cellwidth=5in];
>    define ClaimLine_Allow_Amt / '' analysis sum;
>
> run;
>
> However, in the following report, cellwidth is being ignored:
>
> proc report data = SASUSER.example;
>    where Claim_Incurred_yrmo >= 201001;
>    columns Claim_Class_Id ClaimLine_Allow_Amt,Claim_Incurred_yrmo;
>
>    define Claim_Class_Id / group style(header) = [cellwidth=6in];
>    define Claim_Incurred_yrmo / across style(column) = [cellwidth=5in];
>    define ClaimLine_Allow_Amt / '' analysis sum;
>
> run;
>
>
>
>
> I have a suspicion that this problem is because the report is becoming too
> wide and it's trying to squeeze the report onto a page that's too small and
> thus overriding my explicit cell widths.  Does anyone know how to overcome
> this?
>
> Thanks,
> Sterling
>