Date:         Thu, 19 May 2011 02:46:04 -0400
Reply-To:     Søren Lassen <s.lassen@POST.TELE.DK>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         Søren Lassen <s.lassen@POST.TELE.DK>
Subject:      Re: reading text in multiple lines
Comments: To: Marcel Lamack <mar.lamack@HOTMAIL.COM>
Content-Type: text/plain; charset=ISO-8859-1

LL,
Assuming nothing about length of fields and placement of line breaks,
the data can be read like this:

data test;
  infile cards flowover delimiter='<';
  length var1-var3 dummy $200;
  array vars var:;
  do _N_=1 to dim(vars);
    input @'td> ' vars(_N_) dummy @;
    do while(dummy ne '/td>');
      call catx(' ',vars(_N_),dummy);
      input dummy @;
      end;
    end;
drop dummy;
cards4;
<td> some text 1 </td>
<td> some text 2 </td>
<td> some text some text some text
some text some text some text some text</td>
;;;;run;

Regards,
Søren

On Tue, 17 May 2011 16:03:43 +0000, L... L... <mar.lamack@HOTMAIL.COM>
wrote:

>Dear all, I need to import a txt file like this:
>
><td> some text 1 </td>
><td> some text 2 </td>
><td> some text some text some text
>some text some text some text some text</td>
>.
>.
>.
>I need to create three variables:
>var1: some text 1
>var2:  some text 2
>var3: some text some text some text some text some text some text some text
>
>Please, How can I do this? (sas 9.2)
>
>best regards;
>