Date:         Sun, 20 Sep 1998 12:44:11 GMT
Reply-To:     Andreas Grueninger <grueni@STUTTGART.NETSURF.DE>
Sender:       "SAS(r) Discussion" <SAS-L@UGA.CC.UGA.EDU>
From:         Andreas Grueninger <grueni@STUTTGART.NETSURF.DE>
Organization: LF.net GmbH, Internet Services, Stuttgart, Germany
Subject:      Re: 4th variable on PROC GPLOT

On Fri, 11 Sep 1998 14:16:37 -0700, Jeff.YUAN@ST.COM wrote:
 
>     Hi folks,
>
>     Is there a way to present the information from a 4th variable onto a
>     SAS graph?
>     I got two different curves for two products. But, I like to know each
>     Value comes from which Equipmnt. Is there a way I can put different
>     symbol for different Equipmnt on the curve?  (e.g. '@' for cd01, '#'
>     for cd02, '$'for cd03 on the curve)
 
You may use a annotate dataset as follows:
Adapt the value of style, text etc. to your system.
 
DATA test;
   LENGTH product Equipmnt $8;
   INPUT week   Value   product Equipmnt;
CARDS;
     1          23      cc      cd01
     2          34      cc      cd01
     3          35      cc      cd02
     4          41      cc      cd01
     5          26      cc      cd02
     6          32      cc      cd03
     7          45      cc      cd02
     1          24      dd      cd01
     2          33      dd      cd02
     3          36      dd      cd01
     4          42      dd      cd01
     5          28      dd      cd02
     6          34      dd      cd03
     7          41      dd      cd03
;
RUN;
DATA anno;
   LENGTH style function $8 text $20;
   RETAIN color 'black' ysys '2' xsys '2' position '5' style
'HWCGM001'
          function 'LABEL';
   SET test (KEEP=value week equipmnt RENAME=(value=y week=x));
   SELECT (equipmnt);
      WHEN ('cd01') text = '1';
      WHEN ('cd02') text = '2';
      WHEN ('cd03') text = '3';
      OTHERWISE;
   END;
RUN;
symbol1 interpol=join;
proc gplot DATA=test;
     plot value*week=product / ANNO=anno;
RUN;
QUIT;
 
---------------------------
Andreas Grueninger
 
PRIVATE: grueni@stuttgart.netsurf.de
 OFFICE: grueninger@lfl.bwl.de
---------------------------